# GNUPLOT 4.0 script to plot Planck's
# spectral distribution of emissive power
#
# Gnuplot can be downloaded from http://www.gnuplot.info
#
# Author: Manuel Gimond (gimond@fugadeideas.org)
# Released to the public domain with no warranty of any kind
#
# List of constants:
#
# h   = Planck's constant (Js)
# c   = speed of light (cm/s)
# T   = skin temperature (K)
# k   = Boltzmann's constant (W/K)
# WW  = nm to cm conversion

reset
set grid
set logscale y
set mytics 10
set xrange[-10:10]
set yrange [1:*]
set format y "%2.1tE%1T"
set xlabel "Wavelength (nm)"

# Constants
PI = 3.1415927
h  = 6.26075E-34
c  = 2.9979E10
k  = 1.38E-23
C1 = h*c**2
C2 = h*c/k
WW = 1E-7

# Planck's spectral distribution (W/cm2/µm and BTU/hr/ft2/µm)

# Output in W/cm2/µm (uncomment the following line and comment lines 42-43)
# I(x) = 2*PI * C1 / ( (x*WW)**5 * (exp(C2/((x*WW)*T))-1))
# set ylabel "Hemispherical spectral emissive power (W/m2/µm)"

# Output in BTU/hr/ft2/µm
I(x) = 2*PI * C1 / ( (x*WW)**5 * (exp(C2/((x*WW)*T))-1)) * 0.3174
set ylabel "Hemispherical spectral emissive power (Btu/hr/ft2/µm)"

set dummy x

# Set wavelength range (in nm)
set xrange [000:30000]

plot  T=5555,I(x) title "T=5555K",\
      T=300 ,I(x) title "T=300K",\
      T=833 ,I(x) title "T=833K"